Array and List

Array

Arrays are our main ordered data structure. They work the same way as JavaScript arrays: they can be randomly accessed, dynamically resized, updated, etc.

let myArray = ["hello", "world", "how are you"]

ReScript arrays' items must have the same type, i.e. homogeneous.

Usage

Access

Accessing items in an array will return an option and can be done like so:

let myArray = ["hello", "world", "how are you"]

let firstItem = myArray[0] // Some("hello")

let tenthItem = myArray->Array.get(10) // None

Update

Items in an array can be updated by assigning a value to an index or using a function:

let myArray = ["hello", "world", "how are you"]

myArray[0] = "hey" // now ["hey", "world", "how are you"]

myArray->Array.push("?") //  ["hey", "world", "how are you", "?"]

myArray->Array.set(0, "bye") //  ["bye", "world", "how are you", "?"]

Array spreads

Since 11.1

You can spread arrays of the the same type into new arrays, just like in JavaScript:

let y = [1, 2]
let x = [4, 5, ...y]
let x2 = [4, 5, ...y, 7, ...y]
let x3 = [...y]

Note that array spreads compiles to Belt.Array.concatMany right now. This is likely to change to native array spreads in the future.

List

ReScript provides a singly linked list too. Lists are:

• immutable

• fast at prepending items

• fast at getting the head

• slow at everything else

let myList = list{1, 2, 3}

Like arrays, lists' items need to be of the same type.

Usage

You'd use list for its resizability, its fast prepend (adding at the head), and its fast split, all of which are immutable and relatively efficient.

Do not use list if you need to randomly access an item or insert at non-head position. Your code would end up obtuse and/or slow.

For accessing deeper, see destructuring.

Immutable Prepend

Use the spread syntax:

let myList = list{1, 2, 3}
let anotherList = list{0, ...myList}

myList didn't mutate. anotherList is now list{0, 1, 2, 3}. This is efficient (constant time, not linear). anotherList's last 3 elements are shared with myList!

Note that list{a, ...b, ...c} was a syntax error before compiler v10.1. In general, the pattern should be used with care as its performance and allocation overhead are linear (O(n)).

Access

switch (described in the pattern matching section) is usually used to access list items:

let message =
  switch myList {
  | list{} => "This list is empty"
  | list{first, second, ...rest} => "The list two items and a potenial remainder of items"
  | list{a, ...rest} => "The head of the list is the string " ++ Int.toString(a)
  }